1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
|
;------------------------------------------------------------------------------
; @file
; Intel TDX APs
;
; Copyright (c) 2021 - 2022, Intel Corporation. All rights reserved.<BR>
; SPDX-License-Identifier: BSD-2-Clause-Patent
;
;------------------------------------------------------------------------------
%include "TdxCommondefs.inc"
;
; Note: BSP never gets here. APs will be unblocked by DXE
;
; R8 [31:0] NUM_VCPUS
; [63:32] MAX_VCPUS
; R9 [31:0] VCPU_INDEX
;
ParkAp:
do_wait_loop:
;
; register itself in [rsp + CpuArrivalOffset]
;
mov rax, 1
lock xadd dword [rsp + CpuArrivalOffset], eax
inc eax
.check_arrival_cnt:
cmp eax, r8d
je .check_command
mov eax, dword[rsp + CpuArrivalOffset]
jmp .check_arrival_cnt
.check_command:
mov eax, dword[rsp + CommandOffset]
cmp eax, MpProtectedModeWakeupCommandNoop
je .check_command
cmp eax, MpProtectedModeWakeupCommandWakeup
je .do_wakeup
cmp eax, MpProtectedModeWakeupCommandAcceptPages
je .do_accept_pages
; Don't support this command, so ignore
jmp .check_command
.do_accept_pages:
;
; Read the top stack address from arguments
mov rsi, [rsp + AcceptPageArgsTopStackAddress]
;
; Calculate the top stack address of the AP.
; ApStackAddr = BaseStackAddr + (vCpuIndex) * ApStackSize
xor rdx, rdx
xor rbx, rbx
xor rax, rax
mov eax, [rsp + AcceptPageArgsApStackSize]
mov ebx, r9d ; vCpuIndex
mul ebx
add rsi, rax ; now rsi is ApStackAddr
.start_accept_pages:
;
; Read the function address which will be called
mov rax, [rsp + WakeupVectorOffset]
;
; vCPU index as the first argument
mov ecx, r9d
mov rdx, [rsp + AcceptPageArgsPhysicalStart]
mov r8, [rsp + AcceptPageArgsPhysicalEnd]
; save the Mailbox address to rbx
mov rbx, rsp
;
; set AP Stack
mov rsp, rsi
nop
; save rax (the Mailbox address)
push rbx
call rax
; recove rsp
pop rbx
mov rsp, rbx
;
; recover r8, r9
mov rax, 1
tdcall
mov eax, 0FFFFFFFFh
lock xadd dword [rsp + CpusExitingOffset], eax
dec eax
.check_exiting_cnt:
cmp eax, 0
je do_wait_loop
mov eax, dword[rsp + CpusExitingOffset]
jmp .check_exiting_cnt
.do_wakeup:
;
; BSP sets these variables before unblocking APs
; RAX: WakeupVectorOffset
; RBX: Relocated mailbox address
; RBP: vCpuId
;
mov rax, 0
mov eax, dword[rsp + WakeupVectorOffset]
mov rbx, [rsp + WakeupArgsRelocatedMailBox]
nop
jmp rax
jmp $
|
